terraform.azure.automation/modules/azure_rtb/main.tf

terraform {
  required_version = "~> 0.12.21"
  required_providers {
    azurerm = "~> 1.44"
  }
}

resource "azurerm_route_table" "azrtb" {
  count = length(var.rtbs)

  name                          = var.rtbs[count.index].name
  resource_group_name           = var.rtbs[count.index].resource_group_name
  location                      = var.rtbs[count.index].location
  disable_bgp_route_propagation = var.rtbs[count.index].disable_bgp_route_propagation
  tags                          = var.rtbs[count.index].tags

  dynamic "route" {
    for_each = var.rtbs[count.index].routes
    content {
      name                   = route.key
      address_prefix         = route.value.address_prefix
      next_hop_type          = route.value.next_hop_type # VirtualNetworkGateway, VnetLocal, Internet, VirtualAppliance and None
      next_hop_in_ip_address = route.value.next_hop_in_ip_address # if next_hop_type = VirtualAppliance
    }
  }
  depends_on = [var.azrtb_depends_on]
}